Fields Collection

Fields Collection

Recordset 또는 Record 개체의 모든 Field 개체가 포함됩니다.

 

Recordset 개체에는 Field 개체로 구성된 Fields 컬렉션이 있습니다. 각 Field 개체는 Recordset의 열 하나에 해당합니다.

 

속성

Count property

컬렉션에 있는 개체의 수를 나타냅니다.

 

반환 값

Long 값을 반환합니다.

 

다음 코드는 Authors 테이블의 필드 개수를 출력합니다.

Sub PrintFieldCount()

    Dim dbPath As String
    Dim tableName As String
    Dim connectionString As String
    Dim conn As Object
    Dim rs As Object

    Set conn = CreateObject("ADODB.Connection")
    Set rs = CreateObject("ADODB.Recordset")


    dbPath = "D:\download\Biblio.mdb"
    tableName = "Authors"

    ' 데이터베이스 연결 문자열 설정
    connectionString = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & dbPath

    ' 데이터베이스 연결 열기
    conn.Open connectionString

    ' SQL 쿼리 실행 및 Recordset 열기
    rs.Open "SELECT * FROM Authors", conn

    ' 필드(열) 개수 출력
    Debug.Print "Number of fields: " & rs.Fields.Count

    ' Recordset 및 데이터베이스 연결 닫기
    rs.Close
    Set rs = Nothing

    conn.Close
    Set conn = Nothing

End Sub

' 출력 결과
' Number of fields: 3

Item property

이름이나 서수에 따라 컬렉션의 특정 구성원을 나타냅니다.

 

Syntax
Set object = collection.Item ( Index )

 

반환 값
개체 참조를 반환합니다.

Parameters

Index : 컬렉션에서 개체의 이름이나 서수가 되는 Variant 식입니다.

 

Item 속성을 사용하여 컬렉션의 특정 개체를 반환합니다. Item이 컬렉션에서 Index 인수에 해당하는 개체를 찾을 수 없으면 오류가 발생합니다. 또한 일부 컬렉션은 명명된 개체를 지원하지 않으므로 이러한 컬렉션의 경우 서수 참조를 사용해야 합니다.

Item 속성은 모든 컬렉션의 기본 속성이므로 다음 구문 형식을 사용할 수 있습니다.

collection.Item (Index)
collection (Index)

 

다음 코드는 Authors 테이블에서 Author필드의 첫 번째 값을 출력합니다.

Sub PrintSpecificField()

    Dim dbPath As String
    Dim tableName As String
    Dim connectionString As String
    Dim conn As Object
    Set conn = CreateObject("ADODB.Connection")

    Dim rs As Object
    Set rs = CreateObject("ADODB.Recordset")

    dbPath = "D:\download\Biblio.mdb"
    tableName = "Authors"

    ' 데이터베이스 연결 문자열 설정
    connectionString = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & dbPath

    ' 데이터베이스 연결 열기
    conn.Open connectionString

    ' SQL 쿼리 실행 및 Recordset 열기
    rs.Open "SELECT * FROM Authors", conn

    ' 첫 번째 레코드로 이동
    If Not rs.EOF Then rs.MoveFirst

    ' "Author" 필드 값 출력
    Debug.Print "Value of FieldName: " & rs.Fields.Item("Author").Value

    ' 결과 집합 및 데이터베이스 연결 닫기
    rs.Close
    Set rs = Nothing

    conn.Close
    Set conn = Nothing

End Sub

' 출력 결과
' Value of FieldName: Steven