슬라이서를 사용하여 데이터 필터링

슬라이서 추가

SlicerCaches.Add2 method

컬렉션에 새 SlicerCache 개체를 추가합니다.

 

Syntax
expression.Add2 (Source, SourceField, Name, SlicerCacheType)

 

expression : SlicerCaches 컬렉션을 나타내는 변수입니다.

 

Source : 필수 사항입니다. 새 SlicerCache 개체가 기반으로 할 데이터 원본입니다. Source 매개 변수에 전달되는 인수는 WorkbookConnection 개체, PivotTable 개체 또는 문자열일 수 있습니다.

PivotTable 개체가 전달되면 연결된 PivotCache 개체가 데이터 원본으로 사용됩니다.

 

문자열이 전달되면 WorkbookConnection 개체의 이름으로 해석되며, 이와 일치하는 WorkbookConnection 개체가 없는 경우 런타임 오류가 발생합니다.

 

SourceField : 필수 사항입니다. 필터링할 데이터 소스의 필드 이름입니다. OLAP가 아닌 데이터 원본의 경우 슬라이서의 기반이 되는 PivotCache 개체의 PivotField 개체 또는 해당 개체의 고유 이름(PivotField.Name 속성 값)을 사용합니다.

OLAP 데이터 원본의 경우 SlicerCache가 기반으로 하는 계층 구조의 MDX 고유 이름을 사용합니다. OLAP 계층 구조의 수준을 지정할 수도 있으며 Excel에서는 해당 계층 구조를 사용합니다.

 

Name : Excel에서 슬라이서 캐시를 참조하는 데 사용하는 이름(SlicerCache.Name 속성 값)입니다. 생략하면 Excel에서 이름이 생성됩니다.

기본적으로 Excel에서는 "Slicer_"를 비OLAP 데이터 원본이 있는 슬라이서의 경우 PivotField.Caption 속성 값과 연결하거나 OLAP 데이터 원본이 있는 슬라이서의 경우 CubeField.Caption 속성 값과 연결합니다(공백은 "_"로 바꿈). ).

통합 문서 네임스페이스에서 이름을 고유하게 만들어야 하는 경우 Excel에서는 생성된 이름 끝에 정수를 추가합니다. 통합 문서 네임스페이스에 이미 존재하는 이름을 지정하면 Add 메서드가 실패합니다.

 

SlicerCacheType : 슬라이서 또는 슬라이서 캐시의 유형을 지정합니다. 데이터 형식은 XlSlicerCacheType입니다.

 

XlSlicerCacheType enumeration (Excel)

Slicers.Add method

새 슬라이서를 만들고 Slicer 개체를 반환합니다.

 

Syntax
expression.Add (SlicerDestination, Level, Name, Caption, Top, Left, Width, Height)

 

expression : Slicers 개체를 나타내는 변수입니다.

 

SlicerDestination : 결과 슬라이서가 배치되는 시트의 이름 또는 해당 시트를 나타내는 Worksheet 개체를 지정하는 String입니다. 대상 시트는 식으로 지정된 Slicers 개체를 포함하는 통합 문서에 있어야 합니다.

Level : OLAP 데이터 원본의 경우 슬라이서 만들기 작업의 기반이 되는 수준의 서수 또는 MDX(다차원 식) 이름입니다. OLAP가 아닌 원본 데이터의 경우 지원되지 않습니다. 

Name : 슬라이서의 이름입니다. 이름이 지정되지 않은 경우 자동으로 생성됩니다. 통합 문서 내의 모든 슬라이서의 이름은 고유해야 합니다.

Caption : 슬라이서의 캡션입니다.

Top : 통합 문서에서 A1 셀의 왼쪽 위 모서리에 상대적인 슬라이서의 초기 세로 위치(포인트)입니다.

Left : 통합 문서에서 A1 셀의 왼쪽 위 모서리에 상대적인 슬라이서의 초기 가로 위치(포인트)입니다.

Width : 슬라이서 컨트롤의 초기 너비(포인트)입니다.

Height : 슬라이서 컨트롤의 초기 높이(포인트)입니다.

 

다음 코드는 표에 슬라이서를 추가하는 예제입니다.

Sub AddSlicerToTable()
    Dim tbl As ListObject
    Dim sC As SlicerCache
    Dim sL As Slicer

    ' ListObject 개체 설정
    Set tbl = Worksheets("Sheet1").ListObjects("Product")

    ' 슬라이서 캐시 생성
    Set sC = ThisWorkbook.SlicerCaches.Add2(tbl, "Country", _
                                            "CountrySlicerCache", XlSlicerCacheType.xlSlicer)

    ' 시트에 슬라이서 추가
    Set sL = sC.Slicers.Add(Worksheets("Sheet1"), , "CountrySlicer", "Choose Countries", _
                            tbl.Range.Top, tbl.Range.Left + tbl.Range.Width + 10, 200, 175)
End Sub

 

다음은 여러 개의 슬라이서를 추가하는 코드입니다.

Sub AddMultipleSlicersToTable()
    Dim tbl As ListObject
    Dim sC1 As SlicerCache
    Dim sC2 As SlicerCache
    Dim sL1 As Slicer
    Dim sL2 As Slicer

    'ListObject 개체 생성
    Set tbl = Worksheets("Sheet1").ListObjects("Product")

    ' Country 필드에 대한 슬라이서 캐시 생성
    Set sC1 = ThisWorkbook.SlicerCaches.Add2(tbl, "Country", _
                                             "CountrySlicerCache", XlSlicerCacheType.xlSlicer)
    ' 워크시트에 슬라이서 추가
    Set sL1 = sC1.Slicers.Add(Worksheets("Sheet1"), , "CountrySlicer", "Choose Countries", _
                              tbl.Range.Top, tbl.Range.Left + tbl.Range.Width + 10, 150, 175)
    ' Product 필드에 대한 슬라이서 캐시 생성
    Set sC2 = ThisWorkbook.SlicerCaches.Add2(tbl, "Product", _
                                             "CountrySlicerCache", XlSlicerCacheType.xlSlicer)
    ' 워크시트에 슬라이서 추가
    Set sL2 = sC2.Slicers.Add(Worksheets("Sheet1"), , "ProductSlicer", "Choose Products", _
                              tbl.Range.Top, tbl.Range.Left + tbl.Range.Width + 175, 150, 175)
End Sub

다음 코드는 피벗 테이블에 슬라이서를 추가하는 예제입니다.

Sub AddSlicerToPivotTable()
    Dim pvt As PivotTable
    Dim sC As SlicerCache
    Dim sL As Slicer
    
    
    Set pvt = Worksheets("Pivot").PivotTables("PivotTable")
    
    
    Set sC = ThisWorkbook.SlicerCaches.Add2(pvt, "Country", "CountrySlicerCache", XlSlicerCacheType.xlSlicer)
    
   
    Set sL = sC.Slicers.Add(Worksheets("Pivot"), , "CountrySlicer", "Choose Countries", _
    pvt.DataLabelRange.Top, _
    pvt.DataBodyRange.Left + pvt.DataBodyRange.Width + 50, _
    200, 200)
    
End Sub

항목 선택하기

SlicerCache.SlicerItems property

슬라이서 캐시에 있는 모든 항목의 컬렉션을 포함하는 SlicerItems 컬렉션을 반환하며 읽기 전용입니다.

 

Syntax
expression.SlicerItems

 

expression : SlicerCache 개체를 나타내는 변수입니다.

 

비고

SlicerCache 개체의 SlicerItems 속성은 통합 문서 범위 또는 목록을 기반으로 하는 피벗 테이블 기반의 슬라이서(SlicerCache.SourceType = xlDatabase) 또는 관계형 데이터 원본을 기반으로 하는 피벗 테이블 기반의 슬라이서 (SlicerCache.SourceType = xlExternal 및 SlicerCache.OLAP = False)에만 적용됩니다.

외부 OLAP 데이터 원본에 연결된 슬라이서(SlicerCache.OLAP = True)의 경우 SlicerItems 속성에 액세스하려고 하면 런타임 오류가 발생합니다. OLAP 데이터 원본의 경우 SlicerCacheLevel 개체의 SlicerItems 속성을 대신 사용합니다.

 

SlicerItem object

슬라이서의 항목을 나타냅니다.

 

비고

슬라이서에서 현재 선택되어 있는 단추를 나타내는 SlicerItem 개체에 액세스하려면 Slicer 개체의 ActiveItem 속성을 사용합니다. 

피벗 테이블을 필터링하는 슬라이서의 모든 항목을 나타내는 SlicerItems 컬렉션에 액세스하려면 Slicer 개체와 연결된 SlicerCache 개체의 SlicerItems 속성을 사용합니다.

OLAP 계층 구조 수준을 필터링하는 슬라이서의 항목을 나타내는 SlicerItems 컬렉션에 액세스하려면 해당 계층 구조 수준을 나타내는 SlicerCacheLevel 개체의 SlicerItems 속성을 사용합니다. 

 

SlicerItem.Name property

슬라이서 항목의 이름을 반환하며 읽기 전용입니다.

Syntax
expression.Name

 

expression : SlicerItem 개체를 나타내는 변수입니다.

 

SlicerItem.Selected property

Slicer 항목이 선택되었는지를 설정하거나 반환합니다. OLAP 데이터 원본과 연결된 슬라이서의 경우 읽기 전용이며, OLAP 데이터 원본과 연결되지 않은 슬라이서의 경우 읽기/쓰기가 가능합니다.

 

Syntax
expression.Selected

 

expression : SlicerItem 개체를 나타내는 변수입니다.

 

비고

True이면 슬라이서 항목이 선택되고 False이면 선택되지 않습니다.

 

다음 코드는 Country 필드 이름이 Australia인 것만 선택합니다.

Sub SelectSlicerItemUsingLoop()
    Dim si As SlicerItem

    With ActiveWorkbook.SlicerCaches("CountrySlicerCache")
        ' Loop through each slicer item in the slicer cache
        For Each si In .SlicerItems
            If si.Name = "Australia" Then
                ' If the slicer item is the one we want, select it
                si.Selected = True
            Else
                ' Otherwise, deselect it
                si.Selected = False
            End If
        Next si
    End With
End Sub

다음 코드는 여러  항목을 선택하는 예제입니다.

Sub SelectMultipleSlicerItems(slicerName As String, selectedValues() As Variant)
    Dim slicerCache As slicerCache
    Dim slicerItems As slicerItems
    Dim slicerItem As slicerItem
    
    ' 슬라이서 캐시 설정
    Set slicerCache = ThisWorkbook.SlicerCaches(slicerName)
    
    ' 슬라이서 캐시의 모든 항목 저장
    Set slicerItems = slicerCache.slicerItems
    
    ' 슬라이서 캐시의 이전 선택 사항을 모두 해제
    slicerCache.ClearManualFilter
    
    ' 선택한 항목들을 슬라이서 캐시에 적용하기 위해 각 항목 순회
    For Each slicerItem In slicerItems
        If IsError(Application.Match(slicerItem.Value, selectedValues, 0)) Then
            ' 만약 해당 항목이 배열에 없다면 선택 해제.
            slicerItem.Selected = False
        Else
            ' 그렇지 않으면 선택.
            slicerItem.Selected = True
        End If
     Next slicerItem
End Sub

Sub TestSelectMultipleSlicerItems()
   Dim countries() As Variant
   
   countries = Array("Australia", "Germany", "United States")
   
   Call SelectMultipleSlicerItems("CountrySlicerCache", countries)
End Sub

슬라이서 필터 초기화

SlicerCache.ClearAllFilters method

슬라이서 캐시 유형에 따라 슬라이서 또는 타임라인에 대한 필터를 지웁니다.

 

Syntax
expression.ClearAllFilters

SlicerCache.ClearManualFilter method

슬라이서 캐시에 대한 수동 필터를 지웁니다.

 

Syntax
expression.ClearManualFilter

 

expression : SlicerCache 개체를 나타내는 변수입니다.

 

다음 코드는 슬라이서 필터 초기화하는 과정을 매크로 기록한 것입니다.

Sub Macro1()
'
' Macro1 Macro
'

'
    ActiveWorkbook.SlicerCaches("CountrySlicerCache").ClearManualFilter
End Sub

 

다음 코드는 슬라이서 이름을 매개변수로 변수로 받아서 처리하도록 수정한 예제입니다.

Sub ClearSlicerFilter(slicerName As String)

    ThisWorkbook.SlicerCaches(slicerName).ClearManualFilter
End Sub

Sub TestClearSlicerFilter()
    Call ClearSlicerFilter("CountrySlicerCache")
End Sub

슬라이서 서식 지정

 

슬라이서 설정은 슬라이서 캐시 속성과 슬라이서 속성에 포함되어 있습니다.

 

다음 코드는 슬라이서 설정을 매크로 기록한 것입니다.

Sub Macro1()
'
' Macro1 Macro
'

'
    With ActiveWorkbook.SlicerCaches("Slicer_Country").Slicers("Country")
        .Caption = "Choose_Countries"
        .DisplayHeader = False
        .slicerCache.CrossFilterType = xlSlicerCrossFilterShowItemsWithDataAtTop
        .slicerCache.SortItems = xlSlicerSortAscending
        .slicerCache.SortUsingCustomLists = True
        .slicerCache.ShowAllItems = True
    End With
End Sub

Slicer.Style property

지정한 슬라이서에 현재 적용된 스타일을 반환하거나 설정하며 읽기/쓰기가 가능합니다.

Slicer.NumberOfColumns property

지정된 슬라이서의 열 수를 반환하거나 설정합니다. 읽기/쓰기가 가능합니다.

 

매크로 기록을 해보니 Buttons 그룹은 Slice 개체의 속성과 연관이 있습니다.

Sub Macro3()
'
' Macro3 Macro
'

'
    ActiveWorkbook.SlicerCaches("Slicer_Country").Slicers("Country"). _
            NumberOfColumns = 3
    ActiveWorkbook.SlicerCaches("Slicer_Country").Slicers("Country").RowHeight = _
    21.6
    ActiveWorkbook.SlicerCaches("Slicer_Country").Slicers("Country").RowHeight = _
    28.8
    ActiveWorkbook.SlicerCaches("Slicer_Country").Slicers("Country").RowHeight = 36


    ActiveWorkbook.SlicerCaches("Slicer_Country").Slicers("Country").ColumnWidth = _
    43.2
    ActiveWorkbook.SlicerCaches("Slicer_Country").Slicers("Country").ColumnWidth = _
    36
    ActiveWorkbook.SlicerCaches("Slicer_Country").Slicers("Country").ColumnWidth = _
    28.8

End Sub

 

사이즈 그룹은 Shapes object의 속성과 연관이 있습니다.

Sub Macro4()
'
' Macro4 Macro
'

'
    ActiveSheet.Shapes("Country").Height = 64.8
    ActiveSheet.Shapes("Country").Height = 57.6
    ActiveSheet.Shapes("Country").Width = 396
    ActiveSheet.Shapes("Country").Width = 388.8

End Sub

다른 피벗 테이블에서 슬라이서 사용 가능

SlicerPivotTables.AddPivotTable method

피벗 테이블에 대한 참조를 SlicerPivotTables 컬렉션에 추가합니다.

 

다음 코드는 두 번째 피벗테이블을 기존 슬라이서에 추가하는 예제입니다.

Sub AddPivotTableToSlicerCache()
    Dim sc As slicerCache
    Dim pt1 As PivotTable
    Dim pt2 As PivotTable
    
    ' 첫 번째 및 두 번째 피벗테이블 참조 설정
    Set pt1 = Worksheets("Sheet1").PivotTables(1)
    Set pt2 = Worksheets("Sheet1").PivotTables(2)
    
    ' 첫 번째 피벗테이블로부터 슬라이서 캐시 생성
    Set sc = ActiveWorkbook.SlicerCaches.Add(pt1, "Product") ' 여기에서 "Field_Name"은 실제 필드 이름으로 대체되어야 합니다.
    
    ' 슬라이서 캐시에 두 번째 피벗테이블 추가
    sc.PivotTables.AddPivotTable pt2
End Sub

 

다음 코드는 다른 방식의 코드입니다.

Sub AddPivotTableToSlicerCache()
    Dim pvts As SlicerPivotTables
    
    ' "Slicer_Customer" 슬라이서 캐시의 PivotTables 컬렉션 참조 설정
    Set pvts = ThisWorkbook.SlicerCaches("Slicer_Product").PivotTables
    
    ' 해당 컬렉션에 현재 활성화된 워크시트의 "PivotTable2" 피벗테이블 추가
    pvts.AddPivotTable ActiveSheet.PivotTables("PivotTable2")
End Sub

 

슬라이서 연결 끊기

SlicerPivotTables.RemovePivotTable method

피벗 테이블에 대한 참조를 SlicerPivotTables 컬렉션에서 제거합니다. 

 

다음 코드는 두 번째 피벗테이블을 제거합니다.

Sub RemovePivotTableFromSlicerCache()
    Dim pvts As SlicerPivotTables
    
    ' "Slicer_Product" 슬라이서 캐시의 PivotTables 컬렉션 참조 설정
    Set pvts = ThisWorkbook.SlicerCaches("Slicer_Product").PivotTables
    
    ' 해당 컬렉션에서 현재 활성화된 워크시트의 "PivotTable2" 피벗테이블 제거
    pvts.RemovePivotTable (ActiveSheet.PivotTables("PivotTable2"))
End Sub

다음 코드는 모든 피벗테이블을 제거합니다.

Sub RemoveAllPivotTablesFromSlicerCache()
    Dim pvts As SlicerPivotTables
    Dim i As Integer
    
    ' "Slicer_Product" 슬라이서 캐시의 PivotTables 컬렉션 참조 설정
    Set pvts = ActiveWorkbook.SlicerCaches("Slicer_Product").PivotTables
    
    ' 해당 컬렉션에서 모든 피벗테이블 제거 (역순으로 처리)
    For i = pvts.Count To 1 Step -1
        pvts.RemovePivotTable (pvts.Item(i))
    Next i
End Sub

슬라이서 삭제

Slicer.Delete method

슬라이서를 삭제하고 연결된 Slicers 컬렉션에서 해당 슬라이서를 제거합니다.

 

Syntax
expression.Delete

 

expression : Slicer 개체를 나타내는 변수입니다.

 

다음 코드는 슬라이서 삭제를 매크로 기록한 것입니다.

Sub DeleteSlicer()
'
' DeleteSlicer Macro
'

'

    ThisWorkbook.SlicerCaches("Slicer_Product").Slicers("Product").Delete
End Sub

--------------------------------------------------------------------------------------------------------------------------------------------------

Timeline 추가

다음 코드는 타임라인을 추가하는 예제입니다.

Sub AddTimelineSlicer()

    Dim wb As Workbook
    Dim ws As Worksheet
    Dim pt As PivotTable
    Dim sc As slicerCache
    
    Set wb = ThisWorkbook
    Set ws = wb.Sheets("Sheet1")
    
    Set pt = ws.PivotTables("PivotTable1")
    
    ' 타임라인 슬라이서 추가하기
    Set sc = wb.SlicerCaches.Add2(pt, "Date", , xlTimeline)
    
    ' 슬라이서 위치와 크기 설정하기 (위쪽, 왼쪽, 너비, 높이)
    sc.Slicers.Add ws, , "Date", "Date", 233.25, 580.5, 262.5, 108

End Sub

Timeline을 사용하여 기간을 기준으로 필터링

TimelineViewState object

슬라이서 뷰의 타임라인 특정 멤버를 나타냅니다.

 

Timeline 표시 설정

TimelineViewState.ShowHeader property

컨트롤의 헤더 표시 여부를 가져오거나 설정합니다. 읽기/쓰기 가능한 Boolean입니다.

 

Syntax
expression.ShowHeader

 

expression : TimelineViewState 개체를 나타내는 변수입니다.

TimelineViewState.ShowHorizontalScrollbar property

컨트롤의 가로 스크롤 막대가 표시되는지 여부를 가져오거나 설정합니다. 읽기/쓰기 가능한 Boolean입니다.

 

Syntax
expression.ShowHorizontalScrollbar

 

expression : TimelineViewState 개체를 나타내는 변수입니다.

TimelineViewState.ShowSelectionLabel property

컨트롤의 필터 선택 레이블이 표시되는지 여부를 가져오거나 설정합니다. 읽기/쓰기 가능한 Boolean입니다.

 

Syntax
expression.ShowSelectionLabel

 

expression : TimelineViewState 개체를 나타내는 변수입니다.

TimelineViewState.ShowTimeLevel property

컨트롤의 시간 수준 드롭다운이 표시되는지 여부를 가져오거나 설정합니다.

 

Syntax
expression.ShowTimeLevel

 

expression : TimelineViewState 개체를 나타내는 변수입니다.

 

다음 코드는 표시 설정을 변경하면서 매크로 기록한 예제입니다.

Sub ToggleTimelineViewComponents()
'
' ToggleTimelineViewComponents Macro
'

'
    ActiveWorkbook.SlicerCaches("NativeTimeline_Date").Slicers("Date"). _
        TimelineViewState.ShowHeader = False
    ActiveWorkbook.SlicerCaches("NativeTimeline_Date").Slicers("Date"). _
        TimelineViewState.ShowSelectionLabel = False
    ActiveWorkbook.SlicerCaches("NativeTimeline_Date").Slicers("Date"). _
        TimelineViewState.ShowHorizontalScrollbar = False
    ActiveWorkbook.SlicerCaches("NativeTimeline_Date").Slicers("Date"). _
        TimelineViewState.ShowTimeLevel = False
    ActiveWorkbook.SlicerCaches("NativeTimeline_Date").Slicers("Date"). _
        TimelineViewState.ShowHeader = True
    ActiveWorkbook.SlicerCaches("NativeTimeline_Date").Slicers("Date"). _
        TimelineViewState.ShowSelectionLabel = True
    ActiveWorkbook.SlicerCaches("NativeTimeline_Date").Slicers("Date"). _
        TimelineViewState.ShowHorizontalScrollbar = True
    ActiveWorkbook.SlicerCaches("NativeTimeline_Date").Slicers("Date"). _
        TimelineViewState.ShowTimeLevel = True
End Sub

TimelineViewState.Level property

표시된 수준을 가져오거나 설정합니다. 읽기/쓰기 XlTimelineLevel입니다.

 

XlTimelineLevel enumeration (Excel)

다음 코드는 뷰 상태를 연도로 변경합니다.

Sub ChangeTimelineLevel(slicerCacheName As String, slicerName As String, level As XlTimelineLevel)
    ThisWorkbook.SlicerCaches(slicerCacheName).Slicers(slicerName). _
        TimelineViewState.level = level
End Sub
Sub Test()
    ' "NativeTimeline_Date" 캐시에 있는 "Timeline_Date" 슬라이서의 뷰 상태를 연도 단위로 설정
    ChangeTimelineLevel "NativeTimeline_Date", "Date", xlTimelineLevelYears

    ' 다른 캐시나 다른 슬라이서, 다른 단위에 대해서도 동일한 방식으로 사용 가능
End Sub

Tileline에 필터 설정하기

TimelineState.SetFilterDateRange method

 

Timeline의 필터를 설정합니다.

 

Syntax
expression.SetFilterDateRange (StartDate, EndDate)

 

다음 코드는 2019년 7월 1일부터 2019년 9월30일까지 필터를 설정한 예제입니다.

Sub SetDateRangeFilter()
'
' SetDateRangeFilter Macro
'

'
    ActiveWorkbook.SlicerCaches("NativeTimeline_Date").TimelineState. _
        SetFilterDateRange "7/1/2019", "9/30/2019"
End Sub

 

매크로 기록한 걸 조금 수정했습니다.

Sub SetDateRangeFilter(startDate As String, endDate As String)
'
' SetDateRangeFilter Macro
'

'
    ActiveWorkbook.SlicerCaches("NativeTimeline_Date").TimelineState. _
        SetFilterDateRange startDate, endDate
End Sub

Sub CallSetDateRangeFilter()
    Dim startDate As String
    Dim endDate As String
    
    ' 필터링할 날짜 범위를 설정합니다.
    startDate = #7/1/2019# ' "7/1/2019"
    endDate = #9/30/2019# ' "9/30/2019"
    
        SetDateRangeFilter startDate, endDate
End Sub

Tileline  초기화

SlicerCache.ClearDateFilter method

meline에 대한 필터를 지웁니다.

 

Syntax
expression.ClearDateFilter

 

expression : SlicerCache 개체를 나타내는 변수입니다.

 

다음 코드는 매크로 기록한 코드입니다.(Thisworkbook만 수정)

Sub ClearDateFilter()
'
' ClearDateFilter Macro
'

'
    ThisWorkbook.SlicerCaches("NativeTimeline_Date").ClearDateFilter
End Sub

여러 피벗 테이블에 하나의 타임라인 사용이나 타임라인 사용자 지정 등 다른 것들은 슬라이서와 동일하므로 생략합니다.

 

도움말 출처

 

슬라이서를 사용하여 데이터 필터링 - Microsoft 지원

 

피벗 테이블 타임라인을 만들어 날짜 필터링 - Microsoft 지원

 

관련 글

피벗 테이블 생성하기 - PivotTableWizard 메서드

피벗 테이블 생성하기 - Add 메서드

피벗 테이블 생성하기

피벗 테이블 분석