Cells 속성

Worksheet.Cells property

현재 사용 중인 셀뿐만 아니라 워크시트의 모든 셀을 나타내는 Range 개체를 반환합니다.

 

Syntax

expression.Cells

 

expression : Worksheet 개체를 나타내는 변수입니다.

 

비고

Item 속성은 Range 개체의 기본 속성 (기본 속성: 해당 형식의 컨트롤을 새로 만들 때마다 같은 값이 적용되도록 컨트롤에 설정할 수 있는 속성입니다.)이므로 Cells 키워드 바로 다음에 행과 열 인덱스를 지정할 수 있습니다.

이 속성을 개체 한정자 없이 사용하면 현재 워크시트에 있는 모든 셀을 나타내는 Range 개체를 반환합니다.

예제

1. 특정 셀 값 읽기

Sub ReadCellValue()
    Dim myValue As Variant
    myValue = ThisWorkbook.Sheets("Sheet1").Cells(2, 4).Value
    Debug.Print myValue
End Sub

' Output
' Florida

 

2. 특정 셀에 값 입력하기

Sub WriteToCell()

    Dim ws As Worksheet
    Set ws = Worksheets("Sheet1")

    ' A1부터 시작하여 데이터 쓰기
    ws.Cells(1, 1).Value = "이름"
    ws.Cells(1, 2).Value = "나이"

    ' 다른 셀에 데이터 추가
    ws.Cells(2, 1).Value = "John"
    ws.Cells(2, 2).Value = 30
End Sub

 

3. 특정 범위의 모든 셀 값을 대문자로 변환하기

Sub ConvertRangeToUpperCase(ws As Worksheet, rngAddress As String)
    Dim rng As Range
    Set rng = ws.Range(rngAddress)
    
    Dim cell As Range
    
    For Each cell In rng.Cells
        ' 각 셀의 값을 대문자로 변환합니다.
        cell.Value = UCase(cell.Value)
    Next cell
End Sub

Sub Test()
   Call ConvertRangeToUpperCase(ThisWorkbook.Sheets("Sheet1"), "A2:A20")
End Sub

 

매크로 실행 전

 

매크로 실행 후

 

4. 특정 범위 서식 지정

Sub SetFontItalic()
    ' "Sheet1" 워크시트의 범위 "A1:D10"에서 일부 범위의 글꼴을 기울임체로 설정
    
    ' 워크시트 및 범위 설정
    With Worksheets("Sheet1").Range("A1:D10")
        ' 원하는 부분 범위 설정 (예: 2행부터 5행, 1열부터 3열)
        .Range(.Cells(2, 1), .Cells(5, 3)).Font.Italic = True
    End With
End Sub

 

도움말 출처

 

Worksheet.Cells property (Excel)