엑셀 문서 속성 수정하기

이 글은 도움말을 번역한 글입니다.

 

Workbook.BuiltinDocumentProperties 속성

 

지정한 통합 문서에 대한 기본 제공 문서 속성을 모두 나타내는 DocumentProperties 컬렉션을 반환하며 읽기 전용입니다.

 

Syntax
expression.BuiltinDocumentProperties

 

expression   Workbook 개체를 나타내는 변수입니다.

 

비고
이 속성은 기본 제공 문서 속성의 컬렉션 전체를 반환합니다. 속성 이름이나 컬렉션 인덱스 번호를 지정하여 컬렉션의 단일 구성원(DocumentProperty 개체)을 반환하려면 Item 메서드를 사용합니다.

인덱스 값이나 이름으로 문서 속성을 참조할 수 있습니다. 다음은 사용할 수 있는 기본 제공 문서 속성 이름을 보여 주는 목록입니다.

컨테이너 응용 프로그램에서는 기본 제공 문서 속성마다 값을 정의할 필요가 없습니다. 기본 제공 문서 속성 중 값이 정의되지 않은 속성이 있으면 해당 문서 속성에 대한 Value 속성을 읽을 때 오류가 발생합니다.

Item 메서드는 DocumentProperties 컬렉션의 기본 메서드이므로 다음 두 명령문은 동일합니다.

BuiltinDocumentProperties.Item(1) 
BuiltinDocumentProperties(1)

사용자 지정 문서 속성의 컬렉션을 반환하려면 CustomDocumentProperties 속성을 사용합니다.

다음 코드는 현재 통합 문서의 모든 속성을 출력합니다.

Sub PrintAllDocumentProperties()
    Dim prop As DocumentProperty
    Dim propName As String
    Dim propValue As Variant
    
    On Error Resume Next ' 에러 발생 시 중단하지 않고 다음 코드 실행
    
    ' 현재 통합문서의 내장 문서 속성을 확인합니다.
    For Each prop In ThisWorkbook.BuiltinDocumentProperties
        propName = prop.Name
        propValue = prop.Value
        
        ' 메시지를 출력합니다. 만약 에러가 발생하면 출력하지 않고 다음 속성으로 넘어갑니다.
        Debug.Print "속성 이름: " & propName & ", 값: " & propValue
    Next prop
    
    On Error GoTo 0 ' 에러 처리 설정을 초기화합니다.
End Sub

For Each 대신 For 문을 사용할 수도 있습니다.

Sub PrintAllDocumentProperties()
    Dim prop As DocumentProperty
    Dim propIndex As Long
    Dim propName As String
    Dim propValue As Variant

    On Error Resume Next    ' 에러 발생 시 중단하지 않고 다음 코드 실행

    ' 현재 통합문서의 내장 문서 속성을 확인합니다.
    For propIndex = 1 To ThisWorkbook.BuiltinDocumentProperties.Count
        Set prop = ThisWorkbook.BuiltinDocumentProperties.Item(propIndex)

        propName = prop.Name
        propValue = prop.Value

        ' 메시지를 출력합니다. 만약 에러가 발생하면 출력하지 않고 다음 속성으로 넘어갑니다.
        Debug.Print "속성 이름: " & propName & ", 값: " & propValue

    Next propIndex

    On Error GoTo 0    ' 에러 처리 설정을 초기화합니다.
End Sub

다음 코드는 작성자를 변경합니다.

Sub UpdateAuthor()
    ThisWorkbook.BuiltinDocumentProperties("Author") = "홍길동"
End Sub

 

다음 코드는 생성일을 변경합니다.

Sub UpdateCreatedDate()
    ThisWorkbook.BuiltinDocumentProperties("Creation Date") = #7/12/2020#
End Sub

* VBA를 사용하지 않고도 속성 변경이 가능합니다.이것은 그냥 공부 차원의 예제입니다.